クリップボードの中身を直接印刷します。下の例では、印刷する ためのエディタに「メモ帳」を使っています。
 尚、 「AutoItX」が、必要です。

***** (例)C:\Script\PrintCb.vbs *****

'//////////////////////////////////////////////////////////
'//
'//     クリップボードの中身を印刷(要AutoItX)
'//
Option Explicit

Dim objAutoIt, objFS, objFile, objWshShell
Dim myClip, fileTemp
Dim res

'//クリップボードを取得
Set objAutoIt = CreateObject("AutoItX.Control")
myClip = objAutoIt.ClipGet()

'//クリップボードがNULLなら終了
If myClip = "" Then
    MsgBox "クリップボードの中身がありません。",48
    WScript.Quit
End If

'//テンポラリ用フォルダがあるか? なければ作る
Set objFS = CreateObject("Scripting.FileSystemObject")
If objFS.FolderExists("C:\Script\temp") = False Then
    objFS.CreateFolder("C:\Script\temp")
End If

'//テンポラリファイルを作成
fileTemp = objFS.GetTempName
Set objFile = objFS.CreateTextFile("C:\Script\temp\" & fileTemp)

'//クリップボードの内容をテンポラリファイルに書き込む
objFile.Write(myClip)
objFile.Close

'//メモ帳を使って印刷
Set objWshShell = WScript.CreateObject("WScript.Shell")
objWshShell.Run "notepad /p C:\Script\temp\" & fileTemp ,0,1

'//テンポラリファイルを削除する
objFS.DeleteFile "C:\Script\temp\" & fileTemp



戻る