テキストファイルを作ってエディターで開きます。

 今回は、拡張子によって、読み込む雛形変えています。


【実行画面】



 下の例では、"OpNewTxt.vbs" と各サンプルファイルは、 "C:\Script" にあり、エディタは"K2Editor" というのを 使っています。


***** OpNewTxt.vbs *****

'////////////////////////////////////////////////////////////////////
'//
'//     テキストファイルを作ってエディターで開く
'//     (拡張子によって、それぞれの雛形を読み込む)
Option Explicit

Dim objFS, objFile, WshShell
Dim newfile, ext

'//入力した名前によってテキストファイルを作る
Set objFS = CreateObject("Scripting.FileSystemObject")
newfile = InputBox("新規ファイル名を入れて下さい。" & vbCR & vbCR &_
            "ファイルを作成しエディタで開きます。","新規テキストファイル作成")

If newfile = "" Then
    WScript.Quit
Else
    '//テキストファイルを新しく作る
    Set objFile = objFS.CreateTextFile(newfile,False)
    '//入力したファイル名の拡張子を調べる
    ext = objFS.GetExtensionName(newfile)
End If


'//拡張子がhtml,hta,vbsなら雛形を書き込む
If ext = "html" Or ext = "HTML" Or _
        ext = "htm" Or ext = "HTM" Or _
        ext = "hta" Or ext = "HTA" Or _
        ext = "vbs" Or ext = "VBS" Then
    Call Wr_Samp(ext)
End If
objFile.Close   '//作成したファイルを閉じる

'//エディタで開く
Set WshShell = Wscript.CreateObject("Wscript.Shell")
WshShell.Run("C:\PROGRA~1\k2e\K2Editor.exe " + newfile)



'//////////////////////////////////////
'//     雛形書き込み処理

Sub Wr_Samp(str)
    Dim objSamp
    Dim myTempl, nameSamp
    
    '//サンプルファイルを選択
    '//     htmlの時は"sample.html"
    If str = "html" Or str = "HTML" Or _
            str = "htm" Or str = "HTM" Then
        nameSamp = "C:\Script\sample.html"
    '//     htaの時は"sample.hta"
    ElseIf str = "hta" Or str = "HTA" Then
        nameSamp = "C:\Script\sample.hta"
    '//     vbsの時は"sample.vbs"
    ElseIf str = "vbs" Or str = "VBS" Then
        nameSamp = "C:\Script\sample.vbs"
    End If
        
    '//雛形読み込み
    Set objSamp = objFS.OpenTextFile(nameSamp)
    myTempl = objSamp.ReadAll
    objSamp.Close
    '//雛形書き込み
    objFile.Write(myTempl)

End sub



戻る