コマンドライン引数からテキスト形式のリストを作ります。

【実行画面】



***** MakeList.vbs *****

'////////////////////////////////////////////////////////////////////
'//
'// 引数で渡された要素からテキスト形式のリストを作る
'//
'//                                                 2004年10月31日
Option Explicit
Dim args
Dim myMember
Dim myName, myStr
Dim res1
Dim objFS, objFile

'//コマンドライン引数があるか調べる
'//     コマンドライン引数が渡されていなければ終了
Set args = Wscript.Arguments
If args.Count = 0 Then
    MsgBox "コマンドライン引数がありません", 48,_
        "パラメータ引数からリストを作成"
    WScript.Quit
End If

'// ファイルシステムオブジェクトを作成する
Set objFS = CreateObject("Scripting.FileSystemObject")
res1 = 6    'ひとまず「上書きする」に設定

Do
    '// ファイル名入力用のインプットボックス
    myName = InputBox(_
        "パラメータ引数からテキスト形式のリストを作成します。" &_
        vbCR & vbCR &"出力用ファイルの名前を入力してください。",_
        "パラメータ引数からリストを作成する","newlist.txt")
    '// 「キャンセル」または未入力で終了
    If myName = "" Then
        WScript.Quit
    End If
    
    '// 同名ファイルが存在するかのチェック
    If objFS.FileExists(myName) Then
        res1 = MsgBox("同名ファイルが既に存在します。" & vbCR &_
            "上書きしていいですか?", 36, "同名ファイルがあります。")
    End If
    If res1 = 6 Then
        Exit Do
    End If
    
Loop

'// リスト出力用のテキストファイルを作成
Set objFile = objFS.CreateTextFile(myName)

'// パラメータでリストを書き込む
For Each myMember In args
    objFile.WriteLine(myMember)
Next
objFile.Close

MsgBox "リストを作成しました。", 64 , "リスト作成完了"


【Pyxis 設定例】


 Pyxis(シェアウェア)の入手先は、 ベクター内または、 〜Tom〜さんのページにて



戻る