これは、画像ファイルの形式を一括変換する、 画像コンバータです。

 ただし、signal9様作の "Doodle2" という、コンポーネントが必要です。 インストールの仕方については、付属の説明を参考にしてください。


【実行画面】



 使い方は、変換したい画像ファイルのパスを引数として、スクリプトを 起動します。例えば、変換したい複数のファイルを選択状態にしておいて、 それごと、スクリプトのアイコンにドラッグ&ドロップします。


***** ImgCnv.vbs *****

'////////////////////////////////////////////////////////////////////
'//
'//     画像ファイル コンバータ          Shimizu
'//
'//                                                 2003年10月27日
Option Explicit

Dim typeImg, newName
Dim myItem
Dim objCv, objFS
Dim dFile, resL


'//ファイルが指定されているかいるか調べる
'//     渡されていなければ終了
If Wscript.Arguments.Count = 0 Then
    MsgBox "ファイルが指定されていません。",48
    WScript.Quit
End If


'//変換形式指定のためのインプットボックス
Do

    typeImg = Inputbox("変換形式を拡張子で指定してください。" & vbCr &_
         vbCr &_
         "指定できる拡張子は、bmp/jpg/jpeg/gif/png のいずれかです。" &_
         vbCr & vbCr & "(注意)" & vbCr &_
         "保存先に同名ファイルがある場合は、上書きされます。", _
         "画像コンバータ")
    
    '//拡張子が有効かをチェック
    If LCase(typeImg) = "bmp" Or _
        LCase(typeImg) = "jpg" Or _
        LCase(typeImg) = "jpeg" Or _
        LCase(typeImg) = "gif" Or _
        LCase(typeImg) = "png" Then
            Exit Do
    ElseIf typeImg = "" Then
        WScript.Quit
    Else
        MsgBox "拡張子が有効ではありません。", 48
    End If
    
Loop


'//変換後に、元のファイルを残すかどうかの問い合わせ
dFile = MsgBox("画像ファイルを、" & typeImg & " 形式に、変換します。" &_
    vbCr & vbCr & "変換後に、元のファイルを削除しますか?" & vbCr &_
    "削除する場合は「はい」、しない場合は「いいえ」", 291)
If dFile = 2 Then
    WScript.Quit
End If


'//変換処理
For Each myItem in Wscript.Arguments

    '//myItemから新しいファイル名を作る
    Set objFS = CreateObject("Scripting.FileSystemObject")
    newName = objFS.GetBaseName(myItem) & "." & typeImg
    
    '//ファイルから画像を読み込む
    Set objCv = CreateObject("Doodle2.MyCanvas")
    resL = objCv.LoadFromFile(myItem)
    Select Case resL
    Case -1
        MsgBox myItem & " が、ありません。", 48
    Case -2
        MsgBox myItem & " は、有効な形式のファイルではありません。", 48
    Case 0
        '//画像をファイルに保存
        objCv.SaveToFile(newName)
        If dFile = 6 Then
            objFS.DeleteFile myItem     '//元のファイルを削除
        End If
    End Select
    
Next


MsgBox "変換が完了しました。", 64


 Pyxis でのランチャー設定例は、
"ImgCnv.vbs" "C:\Script" 内にあるとして、)


 Pyxis(シェアウェア)の入手先は、 ベクター内、または、 〜Tom〜さんのページにて



戻る