「メモ帳」を使って日記を付けます。
< VBScript >

'//////////////////////////////////////////////////////////
'//
'//     メモ帳を使って日記をつける
'//
Option Explicit
Dim objFS, objWshShell, objFile, objAutoIt
Dim strFolder, strFile, strPath

'//日記用フォルダのパス("マイドキュメント\Diary")を取得する
Set objWshShell = WScript.CreateObject("WScript.Shell")
strFolder = objWshShell.SpecialFolders("MyDocuments") & "\Diary"

'//日記用フォルダが存在するか調べる
'//     フォルダが無ければ作る
Set objFS = CreateObject("Scripting.FileSystemObject")
If objFS.FolderExists(strFolder) = False Then
    objFS.CreateFolder(strFolder)
End If

'//日記用ファイルのパスを取得する
strFile = Mid(Date,1,2) & Mid(Date,4,2) & ".dia"
strPath = strFolder & "\" & strFile

'//日記用ファイルが存在するか調べる
'//     無ければ作る
If objFS.FileExists(strPath) = False Then
    Set objFile = objFS.CreateTextFile(strPath)
    objFile.WriteLine(".LOG")
    objFile.Close
End If

'//「メモ帳」でファイルを開く
objWshShell.Run "notepad """ & strPath & """"

'//日本語入力をONにする
Set objAutoIt = CreateObject("AutoItX.Control")
objAutoIt.WinWaitActive strFile, "", 2
objAutoIt.Send "{APPSKEY}o"



戻る