クリップボードの内容で新しくテキスト形式のファイルを作ります。 (テキスト形式のファイルを作って、そこにクリップボードの内容を コピーします。)
 ファイル名を入力する際、拡張子を省略すると、自動的に"txt"が 付けられます。
 尚、コンポーネント (AutoItX) が必要です。

 コードは、以下の通りです。
(下の例では、作ったファイルを開く際に、“K2Editor”というのを 使っています。)
***** ClpNew.vbs *****

'//////////////////////////////////////////////////////////
'//
'//     クリップボードの中身で新しいテキストファイルを作る
'//
Option Explicit

Dim objFS, objFolder, objFile, objAutoIt
Dim newText, myClip

'// ファイル名入力のインプットボックス
newText = InputBox("クリップボード内の内容で新しく" & vbCr &_
    "テキスト形式のファイルを作ります。" & vbCr & vbCr &_
    "ファイル名を入力して下さい。",_
    "クリップボードの中身で新規作成",_
    "newtext.txt")
If newText = "" Then
    WScript.Quit
End If

'// 拡張子の指定がなければ、拡張子を"txt"にする
Set objFS = CreateObject("Scripting.FileSystemObject")
If objFS.GetExtensionName(newText) = "" Then
    newText = objFS.GetBaseName(newText) + ".txt"
End If

'// クリップボードを取得
Set objAutoIt = CreateObject("AutoItX.Control")
myClip =objAutoIt.ClipGet()

'// 新しいテキストファイルを作る
Set objFolder = objFS.GetFolder(".")
Set objFile = objFolder.CreateTextFile(newText)

'// クリップボードの内容を書き込む
objFile.Write(myClip)
objFile.Close

'//ファイルを開くか?
'//     「はい」の場合、エディタで開く
res = MsgBox(newText & "を作成しました。" & vbCr &_
    "このファイルをエディタで開きますか?",35)
If res = 6 Then
    '//ファイルをエディタで開く
    Dim objWshShell
    Set objWshShell = WScript.CreateObject("WScript.Shell")
    objWshShell.Run "C:\PROGRA~1\K2E\K2EDITOR.EXE """ &_
        newText & """"
End If


 ファイラーに登録する際、実行ディレクトリを無指定にすると、 新しいファイルは、現在、開いているディレクトリに作られます。  下は、“Pyxis”での設定例です。
(下の例では、"ClpNew.vbs"は、"C:\Script"内にあります。)



 Pyxis(シェアウェア)の入手先は、 ベクター内または、 〜Tom〜さんのページにて



戻る