下のスクリプト例は、コマンドライン引数で受け取ったファイルを 別名で同じフォルダ内に複製します。


【実行画面】



< VBScript >

'//////////////////////////////////////////////////////////
'//
'//     ファイルを別名で複製する        2004年11月18日改
'//
Option Explicit
Dim args, objFS, objFile
Dim strFName, strExName, newName, strTmPass

'//ファイルが渡されていなければ終了
Set args = Wscript.Arguments
If args.Count = 0 Then
    MsgBox "ファイルが指定されていません",48
    WScript.Quit
End If

'//指定された名前のファイルが無ければ終了
Set objFS = CreateObject("Scripting.FileSystemObject")
If objFS.FileExists(args.Item(0)) = False then
    MsgBox "該当するファイルが有りません",48
    WScript.Quit
End If

'//ファイル名を調べる
strFName = objFS.GetFileName(args.Item(0))
'//ファイルの拡張子を調べる
strExName = objFS.GetExtensionName(args.Item(0))

'//新しい名前を入力
Do
    newName = InputBox("新しい名前を入れて下さい。",_
        "ファイルを別名で複製","newname." & strExName)
    If newName = "" Then
        WScript.Quit
    ElseIf objFS.FileExists(newName) = True Then
        MsgBox "同じ名前のファイルがすでにあります",48
    Else
        Exit Do
    End If
Loop

'//ファイルを新しい名前でコピー
objFS.CopyFile strFName,newName

MsgBox """" & strFName & """ を" & vbCr & """" & newName &_
    """ で複製しました。",64



戻る