IEのメールリンクのところをクリックしたときに起動されるメールソ フトとして、OutLookではなく、AirCraftを使いたい場合、上で、 PAD版を紹介しましたが、これは、 AirCraft自身を起動させる方法です。
 ただし、かなり強引なやり方ですし、 スクリプト以外にも、いくつかの手続きが 必要です。でも、一応、AirCraftのメールパッドが開いて、宛先 に相手のアドレスが入ります。

 順番に説明しますと、
1.「AutoItX」のインストール
 スクリプトの中で、AutoItXというコンポーネントを使っていますの で、まず、AutoItXのインストールが、必要です。
@AutoIt から、「AutoItX」というのをダウンロードします。このサイトでは、 独自のスクリプトエンジンも公開されていますが、ここで使うのは、 「AutoItX」という、ActivXです。ページの下の方にあります。

Aダウンロードした圧縮ファイルを解凍して、"AutoItX.dll"を "C:\WINDOWS\SYSTEM"(NT系ではたぶん、"C:\WINDOWS\SYSTEM32")にコピー します。

BAutoItXをレジストリに登録するために、 "regsvr32 C:\WINDOWS\SYSTEM\AutoItX.dll"(9x系の場合)を実行します。
(アンインストールしたい場合は、 "regsvr32 /u C:\WINDOWS\SYSTEM\AutoItX.dll"の様に"/u"オプションを付 けて実行します。)

2.「新規メール」へのキー割り当て
 AirCraftの「オプション」-「キー設定」-「キー割り当て設定」で、 「メールを作成」に適当なキーを割り当てます。

3.スクリプトを記述
 例えば、"C:\Script"に、下のような、"MailAC.vbs"を記述します。
 下の例では、「新規メール作成」へ"Shift+Ctrl+M"を 割り当てています。
(赤色の部分は、個々の環境によって、違う場合があります。)


***** (例)C:\Script\MailAC.vbs *****

'//////////////////////////////////////////////////////////
'//
'//     IE のメールリンクに AirCraft を
'//         (無理矢理)対応させる
Option Explicit
Dim objAutoIt, objWshShell, objRE
Dim args
Dim strMail, strClip

'//AirCraftが起動されていなければ起動
Set objAutoIt = CreateObject("AutoItX.Control")
Set objWshShell = WScript.CreateObject("WScript.Shell")
If objAutoIt.IfWinExist("AirCraft","") = 0 Then
    objWshShell.Run("C:\AIRCRAFT\AIRCRAFT.EXE")
End If
objAutoIt.WinWaitActive "AirCraft", "", 0

'//新規メールウィンドウを開く
objWshShell.SendKeys("+(^(M))")
objAutoIt.WinWaitActive "メールパッド", "", 0

'//メールアドレスを取得する
Set objRE = New RegExp
objRE.Pattern = "mailto:"
objRE.IgnoreCase = True
objRE.Global = False
Set args = Wscript.Arguments
strMail = objRE.Replace(args.Item(0), "")

'//クリップボードを待避
strClip = objAutoIt.ClipGet()
'//クリップボードにメールアドレスを入れる
objAutoIt.ClipPut strMail

'//宛先を書き込む
objWshShell.SendKeys "+({TAB 8})"
objAutoIt.Send "^v"
objWshShell.SendKeys "{TAB 6}"

'//クリップボードを復帰
objAutoIt.ClipPut strClip


4."URL:MailToプロトコル"への関連付設定
 (Meの場合、)「フォルダオプション」- 「ファイルの種類」で、 「URL:MailToプロトコル」(拡張子:N/A)を選択し、 「詳細設定」を押して開く 「ファイルの種類の編集」ウィン ドウで、既存のアクションを編集 するか、下の図のように、新規作成し、 「既定値に設定」する。



 以上です。


戻る