IEからホームページのメール送り先のところをクリックすると、普通は、 OutlookExpressが起動されてしまいます。メールの管理をAirCraftで、 一本化したい場合これでは面倒です。

 そこで、次にようなスクリプトを使うと、相手のメールアドレスが、宛先に入った状態でエディターが起動され、アップロードディレクトリ内にメール用PADファイルが保存されます。

<<手順>>

@"mail.vbs"という、スクリプトを作ります。(下の説明では、"C:\AirCraft"内に)
Aフォルダオプションの設定を変更します。


<<説明>>

*@について
 "mail.vbs"は、たとえば、以下のようになります。
 「メールを一通ずつ送るタイプ」と「メールをまとめて送れるタイプ」の二タイプを考えてみました。

(注意)


mail.vbs <メールを一通ずつ送るタイプ>
Rem "mail.pad"作成用のスクリプト    by Shimizu  19:42 00/12/11

'すでに、"mail.pad"が存在するか?
Set fs = CreateObject("Scripting.FileSystemObject")
If fs.FileExists("C:\AirCraft\SGT03030\UPLOAD\mail.pad") Then

    '存在する場合は、上書きしてもいいか?
    res = MsgBox("既存のmail.padがあります。" & vbCR &_
         "書き換えてよろしいですか?",49)

    If res = 1 Then

        '上書きする場合は、"mail.pad"を作成
        Call makepad

    End If

Else
    ' "mail.pad"がない場合は、作成
    Call makepad

End IF

'〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜〜
'ここから、"mail.pad"を作る、サブルーチン
Sub makepad

' "mailto:"を"to:"に置き換える
Set args = Wscript.Arguments

Set objRE = New RegExp
objRE.Pattern = "mailto:"
newStr = objRE.Replace(args.Item(0),"to:")


' "mail.pad"を作成
Set f = fs.CreateTextFile("C:\AirCraft\SGT03030\UPLOAD\mail.pad")

f.WriteLine "*mail"
f.WriteLine newStr
f.WriteLine "sub:"
f.WriteBlankLines(3)
f.WriteLine "               清水 shugo.s@nifty.ne.jp"
f.WriteBlankLines(2)
f.WriteLine "/post"
f.Close


' メモ帳で"mail.pad"を開く。
Set WshShell = Wscript.CreateObject("Wscript.Shell")
WshShell.Run("notepad C:\AirCraft\SGT03030\UPLOAD\mail.pad")

End Sub


mail.vbs <メールをまとめて送れるタイプ>
Rem "mail.pad"作成用のスクリプト    by Shimizu

'すでに、"mail.pad"が存在するか?
Set fs = CreateObject("Scripting.FileSystemObject")
If fs.FileExists("C:\AirCraft\SGT03030\UPLOAD\mail.pad") Then

    '存在する場合は、ファイルをオープン
    Set objFile = fs.GetFile("C:\AirCraft\SGT03030\UPLOAD\mail.pad")
    Set f = objFile.OpenAsTextStream(8,0)

Else
    ' "mail.pad"がない場合は、作成
    Set f = fs.CreateTextFile("C:\AirCraft\SGT03030\UPLOAD\mail.pad")

End IF


' "mailto:"を"to:"に置き換える
Set args = Wscript.Arguments

Set objRE = New RegExp
objRE.Pattern = "mailto:"
newStr = objRE.Replace(args.Item(0),"to:")


'雛形の書き込み
f.WriteLine ("*mail")
f.WriteLine newStr
f.WriteLine ("sub:")
f.WriteBlankLines(3)
f.WriteLine ("               清水 shugo.s@nifty.ne.jp")
f.WriteBlankLines(2)
f.WriteLine ("/post")
f.WriteLine ("")

f.Close


' メモ帳で"mail.pad"を開く。
Set WshShell = Wscript.CreateObject("Wscript.Shell")
WshShell.Run("notepad C:\AirCraft\SGT03030\UPLOAD\mail.pad")


*Aについて
 「フォルダオプション」−「ファイルの種類」の「URL : MailTo プロトコル」を例えば、下図のように設定します。

image01.jpg


【おことわり】



戻る