例えば、DOCファイルが、ワード文書なら“Wordpad”で開き、それ以外なら “PyxView”で開くようにするために、以下のようなスクリプトと 拡張子対応設定を考えてみました。

下のスクリプトでは、ワード/ワードパッド文書の 先頭二文字を"ミマ"と仮定していますが、本当にいつもそうなのかわかりません。 ひとまずこれしか思いつかないので、このようにしましたが、もっと、いい 方法があったら誰か教えて下さい。

例えば、まず"C:\Script" 内に、次のような "WdOrTx.vbs" を準備します。

***** C:\Script\WdOrTx.vbs *****

'//////////////////////////////////////////////////////////
'//
'//     DOCファイルをWordpad/PyxViewで開く
'//         (本当に、ワード/ワードパッド文書の頭が、いつも
'//             "ミマ" か知りませんが・・ヒトマズ)
Option Explicit

Dim args, objFS, objFile, objWshShell
Dim myStr

'//コマンドライン引数を参照
Set args = Wscript.Arguments
If args.Count = 0 Then
    MsgBox "ファイルが指定されていません。",48
    WScript.Quit
End If

'//ファイルがあるか調べる
Set objFS = CreateObject("Scripting.FileSystemObject")
If objFS.FileExists(args.Item(0)) = False Then
    MsgBox "指定されたファイルがありません。",48
    WScript.Quit
End If

'//最初の2文字が"ミマ"ならWordpadで開く
'//     そうでない場合は、PyxViewで開く
Set objFile = objFS.OpenTextFile(args.Item(0))
myStr = objFile.Read(2)
objFile.Close

Set objWshShell = WScript.CreateObject("WScript.Shell")
If myStr = "ミマ" Then
    objWshShell.Exec "C:\PROGRA~1\ACCESS~1\WORDPAD.EXE """ &_
        args.Item(0) & """"
Else
    objWshShell.Exec "C:\PROGRA~1\PYXIS\PYXVIEW.EXE """ &_
        args.Item(0) & """"
End If


次に、"doc"の拡張子対応設定で、下のようにします。
(ビューワに指定した方がいいでしょう。)






戻る