ここでは、Pyxisで開いているフォルダに、クリップボード 内の画像イメージをファイルとして保存する方法を紹介します。

ただし、signal9様作の "Doodle2" という、コンポーネントが必要です。 インストールの仕方については、付属の説明を参考にしてください。

例えば、デスクトップ全体をコピーするには、 [Print Screen] を押します。アクティブなウィンドウを コピーするには、[Alt]+[Print Screen] で、できます。そして、下に示したようなスクリプト"Capch.vbs" を Pyxisのランチャーやナンバーランチャーから起動すると、現在のフォルダに コピーした画像イメージがファイルとして保存されます。

【実行画面】




***** Capch.vbs *****

'//////////////////////////////////////////////////////////
'//
'//     画面をキャプチャする
'//
'//                                     2004年11月29日 改
Option Explicit

Dim objCv, objFS
Dim fileName
Dim res, res2

Set objCv = CreateObject("Doodle2.MyCanvas")
'//クリップボードの画像をロード
If objCv.LoadFromClipBoard = -1 Then
    MsgBox "クリップボードに画像がありません。",64
    WScript.Quit
End If

res = 6

Do
    fileName = InputBox("クリップボードの画像をファイルに保存します。" &_
        vbCr & "ファイル名を入力してください。" & vbCr & vbCr &_
        "拡張子には、bmp/jpg/jpeg/gif/png のいずれかを指定して下さい。",_
        "画像ファイル名を入力")

    If fileName = "" Then
        WScript.Quit
    End If

    '//同名ファイルがあるか調べる
    Set objFS = CreateObject("Scripting.FileSystemObject")
    If objFS.FileExists(fileName) = True Then
        res = MsgBox("既に、同名のファイルがあります。" & vbCr &_
            "上書きしますか?" & vbCr & vbCr &_
            "「いいえ」を押すとファイル名入力画面に戻ります。",291)
    End If

    If res = 2 Then     '//キャンセル
        WScript.Quit
    
    ElseIf res = 6 Then
        '//画像をファイルとして保存
        res2 = objCv.SaveToFile(fileName)
    
        If res2 = 0 Then
            '//正常終了
            Exit Do
        ElseIf res2 = -2 Then
            '//拡張子の不正
            MsgBox "拡張子が正しくありません。",48
        Else
            '//異常終了
            MsgBox "保存できませんでした。",16
            WScript.Quit
        End If
    
    End If

Loop

MsgBox "保存しました。",64


“Pyxis”でのナンバーランチャー設定例は、


尚、このページの二つの画像も、このスクリプトで キャプチャしました。


戻る