それでは、まず何か作ってみましょう。

スクリプトエンジンのバージョンを確認してみる

 まずスクリプトエンジンのバージョンを確認してみましょう。

 テキストエディタで、次のように打ち込んで(コピー&ペーストでもいい) 保存しましょう。ファイル名は、例えば "version.vbs" とかにします。 (拡張子は "vbs" です。)

'//スクリプトエンジンのバージョンを確認してみる

MsgBox "Version: " & ScriptEngineMajorVersion &_
    "." & ScriptEngineMinorVersion

 保存したファイルをエクスプローラとかで、ダブルクリックします。 すると、次のようなウィンドウが出ます。




 このように、WSHのプログラミングはテキスト ファイルでプログラムを書いて "vbs" や "js" の拡張子で保存するだけ です。


 こんどは、インプットボックスから、日付を入力して曜日を求めるプログラム を作ってみましょう。

日付を入力して曜日を求めるプログラム

 同じようにして、テキストエディタで下のように打ち込んで(コピー&ペー ストでいい)から保存し、実行(ダブルクリック)してみましょう。

'///////////////////////////////////////////////////////////
'//
'//      日付を入力して曜日を求める
'//
Option Explicit
Dim hizuke, youbi

Do
    '//日付を入力するためのインプットボックスを表示
    hizuke = InputBox("日にちを入力して曜日を調べます。" &_
        vbCR & vbCR &_
        "例)2000/01/01" & vbCR &_
        "    11-11" & vbCR &_
        "    h15-5-5","曜日を調べる")
        
    '//「キャンセル」または未入力で終了
    If hizuke = "" Then
        Exit Do
        
    '//日付だったらその曜日を表示
    ElseIf IsDate(hizuke) then
        youbi = Weekday(hizuke)
        MsgBox WeekdayName(youbi) & "です。",64
        
    '//日付でなかったら、注意を表示して、インプットボックスに戻る
    Else
        MsgBox "入力した値が不正です。",48
    End If
    
Loop

 実行すると、



といったウィンドウが開きます。

 そこで、入力欄に日付を入れて「OK」を押してみましょう。日付の入れ方 は、
  2000/01/01 とかでも
  2000-01-01 とかでも
  平成12年1月1日 とかでも
VBS が日付と認識できれば、何でもいいです。 "10/10" とか入れ ると、今年の10月10日になります。

 とにかく、日付を入れて「OK」を押すと、



といったウィンドウが出ます。


 次からは、 "VBScript" の文法を中心にして説明していきます。



  

「WSH入門」のインデックスへ